E2EE提供了WebSocket的支持。
什么是WebSocket？
WebSocket协议是基于TCP的一种新的网络协议。它实现了浏览器与服务器全双工(full-duplex)通信——可以通俗的解释为服务器主动发送信息给客户端。
WebSocket首次在HTML5规范中被引用为TCP连接，作为基于TCP的套接字API的占位符。[1] WebSocket通信协议于2011年被IETF定为标准RFC 6455，并被RFC7936所补充规范。
本章节目录：
E2EE的WebSocket服务器特性
使用WebSocket服务器流程：
.程序集变量 WS服务器, WebSocket服务器
WS服务器.初始化 (服务器, 9002, , , &WS_收到消息)
WebSocket服务器．初始化([网站服务器], 整数型 端口, [子程序指针 客户进入事件], [子程序指针 客户退出事件], [子程序指针 收到消息事件])
网站服务器：绑定到网站服务器。类型为“网站服务器（JHTTPServer）”，可以被省略。
绑定的主要作用是同步输出日志到服务器日志中，允许为空，当为空的时候错误时将无日志内容输出。网页提交的文本数据和发送给客户的文本数据不会被自动编码。
端口：绑定到的目标端口。可以被省略。如果不设置则默认端口为9002。
客户进入事件：客户进入时触发的子程序。可以被省略。
格式：<无返回值> 客户进入事件([整数] 客户句柄)。客户退出事件：客户退出时触发的子程序。可以被省略。
格式：<无返回值> 客户退出事件([整数] 客户句柄)。收到消息事件：收到客户发送数据时触发的子程序。可以被省略。
格式：<无返回值> 收到消息事件([整数] 客户句柄, [整数] 消息类型, [整数] 消息句柄)。消息类型可以参考“WS类型_”开头常量，消息内容可以通过 WS服务器.取回消息(消息句柄) 获取到(主要是易语言子程序不支持字节集)。
.版本 2
.支持库 e2ee
.子程序 WS_客户进入
.参数 客户句柄, 整数型
.子程序 WS_客户退出
.参数 客户句柄, 整数型
.子程序 WS_收到消息
.参数 客户句柄, 整数型
.参数 消息类型, 整数型
.参数 消息句柄, 整数型
.局部变量 消息, 文本型
.如果真 (消息类型 ＝ #WS类型_文本_Text)
消息 ＝ WS服务器.取回消息文本 (消息句柄)
.如果真结束
执行服务器对象的 启动() 方法
WS服务器.启动 ()
初始化时注册“收到消息事件”。对用户提交的信息进行处理。
示例：
.版本 2
.支持库 e2ee
.支持库 spec
.子程序 WS_收到消息
.参数 客户句柄, 整数型
.参数 消息类型, 整数型
.参数 消息句柄, 整数型
.局部变量 消息, 存取键值表
.局部变量 类型, 整数型
.局部变量 房间, 整数型
.局部变量 昵称, 文本型
.局部变量 发送消息, 文本型
.如果真 (消息类型 ＝ #WS类型_文本_Text)
.如果真 (消息.从JSON载入 (到文本 (WS服务器.取回消息文本 (消息句柄))))
类型 ＝ 消息.取整数 (“编号”)
' // 取回房间和昵称信息
.如果 (类型 ＝ 9)
' // 执行用户登陆
房间 ＝ 消息.取整数 (“房间”)
昵称 ＝ HTML关键字编码 (消息.取文本 (“昵称”))
.判断开始 (房间 ≠ 1 且 房间 ≠ 2) ' // 房间不对
WS服务器.发送文本 (客户句柄, 创建错误 (客户句柄, -9, “请选择正确的聊天室”))
WS服务器.关闭客户 (客户句柄)
.判断 (取文本长度 (昵称) ＝ 0) ' // 昵称不对
WS服务器.发送文本 (客户句柄, 创建错误 (客户句柄, -9, “昵称不能为空”))
WS服务器.关闭客户 (客户句柄)
.判断 (取文本长度 (昵称) ＞ 32) ' // 昵称不对
WS服务器.发送文本 (客户句柄, 创建错误 (客户句柄, -9, “昵称不能大于32个字符”))
WS服务器.关闭客户 (客户句柄)
.默认
' // 成功登陆
WS服务器.设置属性 (客户句柄, “登录”, “1”)
WS服务器.设置属性 (客户句柄, “房间”, 到文本 (房间))
WS服务器.设置属性 (客户句柄, “昵称”, 昵称)
WS服务器.设置通道 (客户句柄, 房间)
WS服务器.发送文本 (客户句柄, 创建成功 (客户句柄, 9, “登录成功”, 昵称))
WS服务器.发送通道文本 (房间, 创建成功 (0, 109, 创建文本 (“欢迎[{1}]进入房间！”, 昵称), “系统消息”))
调试输出 (WS服务器.取客户列表 (0))
.判断结束
返回 ()
.否则
.如果真 (WS服务器.获取属性 (客户句柄, “登录”) ≠ “1”)
WS服务器.发送文本 (客户句柄, 创建错误 (客户句柄, -9, “您还没有登录”))
WS服务器.关闭客户 (客户句柄)
返回 ()
.如果真结束
房间 ＝ 到数值 (WS服务器.获取属性 (客户句柄, “房间”))
昵称 ＝ WS服务器.获取属性 (客户句柄, “昵称”)
.如果结束
' // 通过类型执行操作
.判断开始 (类型 ＝ 1) ' // 发送消息
发送消息 ＝ HTML关键字编码 (消息.取文本 (“内容”))
.如果 (发送消息 ＝ “”)
WS服务器.发送文本 (客户句柄, 创建错误 (客户句柄, -1, “消息不能为空”))
返回 ()
.否则
WS服务器.发送文本 (客户句柄, 创建成功 (客户句柄, 2, “发送成功”))
.如果结束
WS服务器.发送通道文本 (房间, 创建成功 (客户句柄, 1, 发送消息, 昵称))
.默认
.判断结束
.如果真结束
.如果真结束
消息类型可以通过“#WS类型_”常量获取。
消息句柄消息内容的句柄，可通过下面的方式获取到：
取回消息的方法主要用于“收到消息事件”中：
要启用TLS功能非常简单，在初始化方法后加入 初始化WSS()方法即可。
WS服务器.初始化 (服务器, 9002, , &聊天服务器_WS_客户退出, &聊天服务器_WS_收到消息)
WS服务器.初始化WSS (真, , , , , )
初始化WSS() 方法说明：
<逻辑型> WebSocket服务器.初始化WSS()
初始化TLS安全传输层协议。务必在“初始化()”命令之后使用。用来设置是否启用WSS，和配置TLS的相关参数。
如果您的网站已经开启了HTTPS，并且wss请求域名和您的网站域名一致，则直接设置[使用网站配置]参数为真, 忽略其它配置即可。
启用TLS时，[签名文件]参数允许为空，证书没有设置密码时[证书密码]也可以为空。
详细的配置文件对应关系说明，请参考《创建网站和配置》的HTTPS配置(SSL)章节。